6d87da4c59
- Add recursive_mutex
- Make all locking primitives and sleep use common overridable wait/notify support to allow RTOS
implementations to replace WFE/SEV with something more appropriate
- Add busy_wait_ms
64 lines
2.3 KiB
CMake
64 lines
2.3 KiB
CMake
# Pre-initialize the Raspberry Pi Pico SDK, setting up the platform and toolchain and some CMake utility functions
|
|
# This file must be included prior to the project() call
|
|
|
|
# Note: this file is perhaps named badly, as it provides a method pico_sdk_init which
|
|
# the enclosing project calls LATER to actually "initialize" the SDK (by including the CMakeLists.txt from this
|
|
# same directory)
|
|
|
|
if (NOT TARGET _pico_sdk_pre_init_marker)
|
|
add_library(_pico_sdk_pre_init_marker INTERFACE)
|
|
|
|
function(pico_is_top_level_project VAR)
|
|
string(TOLOWER ${CMAKE_CURRENT_LIST_DIR} __list_dir)
|
|
string(TOLOWER ${CMAKE_SOURCE_DIR} __source_dir)
|
|
if (__source_dir STREQUAL __list_dir)
|
|
set(${VAR} 1 PARENT_SCOPE)
|
|
else()
|
|
set(${VAR} 0 PARENT_SCOPE)
|
|
endif()
|
|
endfunction()
|
|
|
|
if (NOT PICO_SDK_PATH)
|
|
set(PICO_SDK_PATH ${CMAKE_CURRENT_LIST_DIR})
|
|
endif ()
|
|
|
|
get_filename_component(PICO_SDK_PATH "${PICO_SDK_PATH}" REALPATH BASE_DIR "${CMAKE_BINARY_DIR}")
|
|
|
|
set(PICO_SDK_PATH ${CMAKE_CURRENT_LIST_DIR} CACHE PATH "Path to the Raspberry Pi Pico SDK" FORCE)
|
|
|
|
list(APPEND CMAKE_MODULE_PATH ${PICO_SDK_PATH}/cmake)
|
|
|
|
include(${CMAKE_CURRENT_LIST_DIR}/pico_sdk_version.cmake)
|
|
include(pico_utils)
|
|
|
|
message("PICO_SDK_PATH is ${CMAKE_CURRENT_LIST_DIR}")
|
|
|
|
include(pico_pre_load_platform)
|
|
|
|
# We want to configure correct toolchain prior to project load
|
|
# todo perhaps this should be included by the platform instead?
|
|
include(pico_pre_load_toolchain)
|
|
|
|
macro(pico_sdk_init)
|
|
if (NOT CMAKE_PROJECT_NAME)
|
|
message(WARNING "pico_sdk_init() should be called after the project is created (and languages added)")
|
|
endif()
|
|
add_subdirectory(${PICO_SDK_PATH} pico-sdk)
|
|
endmacro()
|
|
|
|
macro(add_sub_list_dirs var)
|
|
foreach(LIST_DIR IN LISTS ${var})
|
|
get_filename_component(SHORT_NAME "${LIST_DIR}" NAME)
|
|
message(DEBUG "Including custom CMakeLists.txt ${SHORT_NAME}")
|
|
add_subdirectory(${LIST_DIR} ${SHORT_NAME})
|
|
endforeach()
|
|
endmacro()
|
|
|
|
macro(add_sub_list_files var)
|
|
foreach(LIST_FILE IN LISTS ${var})
|
|
message(DEBUG "Including custom CMake file ${LIST_FILE}")
|
|
include(${LIST_FILE})
|
|
endforeach()
|
|
endmacro()
|
|
endif()
|